home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (DO) / Softdisk Magazette Volume 2, No. 01 (1982-09)(Softdisk)(Side B).zip / Softdisk Magazette Volume 2, No. 01 (1982-09)(Softdisk)(Side B).do / NFL.RANKER.bas < prev    next >
BASIC Source File  |  1996-12-24  |  14KB  |  189 lines
  1. 10  REM **********************   *                       *   *  NFL RANKING SYSTEM   *   *   ORIGINAL CONCEPT    *   *   BY JOSEPH M. FEEHAN *   *                       *
  2. 15  REM                      *   * RE-ORGANIZED AND      *   *  EXPANDED TO HANDLE   *   *    A WHOLE WEEK'S     *   *  GAMES, IMPROVED THE  *   *  PRINTER OUTPUT, AND  *
  3. 20  REM ADDED NESTED MENU    *   *  FEATURES.            *   *        BY:            *   *   DALE E. SALYER      *   *                       *   *************************<CTRL-J><CTRL-J>
  4. 45  REM *                    *      *** DATA STATEMENTS***      *                    *<CTRL-J><CTRL-J>
  5. 50  DATA JANUARY,FEBRUARY,MARCH,APRIL,MAY,JUNE,JULY,AUGUST,SEPTEMBER,OCTOBER,NOVEMBER,DECEMBER
  6. 60  DATA SUNDAY,MONDAY,TUESDAY,WEDNESDAY,THURSDAY,FRIDAY,SATURDAY
  7. 70  DATA ATLANTA,BALTIMORE,BUFFALO,CHICAGO,CINCINNATI,CLEVELAND,DALLAS,DENVER,DETROIT,GREEN BAY,HOUSTON,KANSAS CITY,LOS ANGELES,MIAMI
  8. 80  DATA MINNESOTA,NEW ENGLAND,NEW ORLEANS,NEW YORK GIANTS,NEW YORK JETS,OAKLAND,PHILADELPHIA,PITTSBURGH,ST. LOUIS,SAN DIEGO,SAN FRANCISCO,SEATTLE,TAMPA BAY,WASHINGTON
  9. 90  REM  ONERR STMT GOES HERE.
  10. 100  DIM R(28,3),N$(28),MO$(12),DA$(6),MA(14,2),Y(28)
  11. 110  DEF  FN I(Z) =  INT(Z +.5)
  12. 120 D$ =  CHR$(4):LL = 40
  13. 130  PRINT D$;"OPEN NFL.DATA": PRINT D$;"READ NFL.DATA": FOR I = 1 TO 28
  14. 140  INPUT R(I,1): INPUT R(I,2): INPUT R(I,3): NEXT I: PRINT D$;"CLOSE NFL.DATA"
  15. 150  PRINT D$;"OPEN NFL.MATCHUPS": PRINT D$;"READ NFL.MATCHUPS": FOR I = 1 TO 14
  16. 160  INPUT MA(I,0): INPUT MA(I,1): NEXT I: PRINT D$;"CLOSE NFL.MATCHUPS"
  17. 170  FOR I = 1 TO 12: READ MO$(I): NEXT I
  18. 180  FOR I = 0 TO 6: READ DA$(I): NEXT I
  19. 190  FOR I = 1 TO 28: READ N$(I): NEXT I
  20. 200  FOR I = 1 TO 28:R(I,0) = I: NEXT I
  21. 205  REM <CTRL-J><CTRL-J>*                    *      **** DATE ROUTINE ****      *                    *<CTRL-J><CTRL-J>
  22. 210  IF  PEEK(1016) >99  OR  PEEK(1017) >12  OR  PEEK(1018) >31  THEN DT$ = "": GOTO 250
  23. 220 YR$ =  STR$(1900 + PEEK(1016)):M$ = MO$( PEEK(1017)):DN$ =  STR$( PEEK(1018)):WD$ = "": IF  PEEK(1019) < = 6  THEN WD$ = DA$( PEEK(1019))
  24. 230 DT$ = WD$ +" " +M$ +" " +DN$ +", " +YR$
  25. 244 :
  26. 245  REM *********************    *                      *    *      MAIN MENU       *    *                      *    ************************<CTRL-J>
  27. 250  TEXT : HOME : HTAB 10: PRINT "NFL RANKING PROGRAM"
  28. 260  VTAB 5: PRINT " 1 - INPUT WEEK'S MATCHUPS.": VTAB 7: PRINT " 2 - DISPLAY PREDICTIONS.": VTAB 9: PRINT " 3 - UPDATE RANKINGS.": VTAB 11: PRINT " 4 - DISPLAY RANKINGS.": VTAB 13: PRINT " 5 - SAVE FILES TO DISK.": VTAB 15: PRINT " 6 - END PROGRAM."
  29. 270  VTAB 21: PRINT "WHICH OPTION (1-6) : ";: INPUT "";R$:CH =  VAL(R$): IF CH <1  OR CH >6  THEN 250
  30. 280  ON CH GOTO 500,300,350,400,1050,290
  31. 290  IF UPD  AND   NOT WRIT  THEN  HOME : VTAB 12: PRINT "YOU HAVE CHANGED SOME RANKINGS AND HAVE NOT SAVED THEM TO DISK.": PRINT : PRINT "DO YOU WANT TO SAVE THEM BEFORE QUITTING?";: INPUT "";R$: IF  LEFT$(R$,1) < >"N"  THEN  GOTO 250
  32. 295  TEXT : HOME : VTAB 12: HTAB 16: PRINT "GOOD-BYE": END 
  33. 300  TEXT : HOME : HTAB 8: PRINT "DISPLAY PREDICTIONS MENU"
  34. 310  VTAB 10: PRINT " 1 - PREDICT ALL MATCHUPS.": VTAB 15: PRINT " 2 - PREDICT INDIVIDUAL TEAMS."
  35. 320  VTAB 21: PRINT "WHICH OPTION (1-2, RETURN>=NONE) : ";: INPUT "";R$: IF R$ = ""  THEN 250
  36. 330 CH =  VAL(R$): IF CH <1  OR CH >2  THEN 300
  37. 340  ON CH GOTO 1250,1440
  38. 350  TEXT : HOME : HTAB 10: PRINT "UPDATE RANKINGS MENU"
  39. 360  VTAB 10: PRINT " 1 - UPDATE ALL MATCHUPS.": VTAB 15: PRINT " 2 - UPDATE INDIVIDUAL TEAMS."
  40. 370  VTAB 21: PRINT "WHICH OPTION (1-2, RETURN>=NONE) : ";: INPUT "";R$: IF R$ = ""  THEN 250
  41. 380 CH =  VAL(R$): IF CH <1  OR CH >2  THEN 350
  42. 390  ON CH GOTO 1650,1700
  43. 400  TEXT : HOME : HTAB 9: PRINT "DISPLAY RANKINGS MENU"
  44. 410  VTAB 6: PRINT " 1 - ALPHABETIC ORDER.": VTAB 10: PRINT " 2 - OFFENSIVE RANK ORDER.": VTAB 14: PRINT " 3 - DEFENSIVE RANK ORDER.": VTAB 18: PRINT " 4 - TOTAL TEAM RANK ORDER."
  45. 420  VTAB 21: PRINT "WHICH OPTION (1-4, RETURN>=NONE) : ";: INPUT "";R$: IF R$ = ""  THEN 250
  46. 430 CH =  VAL(R$): IF CH <1  OR CH >4  THEN 400
  47. 440 KEY = CH -1: GOTO 750
  48. 445  REM <CTRL-J><CTRL-J>*                   *       *** PRINTER INIT. ***       *                   *<CTRL-J><CTRL-J>
  49. 450 SLOT = 1: REM  PRINTER SLOT
  50. 460  PRINT D$;"PR#";SLOT
  51. 465  PRINT CHRS$(9);"80N"
  52. 470 LL = 80
  53. 480  RETURN 
  54. 495  REM <CTRL-J><CTRL-J>*                   *       *** INPUT MATCHES ***       *                   *<CTRL-J><CTRL-J>
  55. 500  TEXT : HOME : VTAB 1: HTAB 13: PRINT "INPUT MATCHUPS": VTAB 2: HTAB (40 - LEN(DT$))/2: PRINT DT$
  56. 510  FOR R = 1 TO 28:Y(R) = 0: NEXT R
  57. 520  VTAB 3: HTAB 14: PRINT "TEAM NUMBERS"
  58. 530  FOR I = 1 TO 14: VTAB 4 +I: HTAB 1: IF I <10  THEN  PRINT " ";
  59. 540  PRINT I;"- ";N$(I);: HTAB 21: PRINT I +14;"- ";N$(I +14)
  60. 550  NEXT I: VTAB 20: HTAB 13: PRINT "GAME #"
  61. 560  POKE 34,21
  62. 570  FOR Z = 1 TO 14: VTAB 20: HTAB 20: PRINT Z
  63. 580  VTAB 22: HTAB 1: CALL  -958: INPUT "  HOME TEAM # =>";R$:R =  VAL(R$)
  64. 590  IF R <1  OR R >28  THEN 610
  65. 600  IF Y(R) = 0  THEN MA(Z,0) = R:Y(R) = 1: GOTO 620
  66. 610  VTAB 23: PRINT "<CTRL-G>INVALID TEAM # - TRY AGAIN!!": FOR DD = 1 TO 500: NEXT : GOTO 580
  67. 620  VTAB 22: HTAB 1: CALL  -958: INPUT "  AWAY TEAM # =>";R$:R =  VAL(R$)
  68. 630  IF R <1  OR R >28  THEN 650
  69. 640  IF Y(R) = 0  THEN MA(Z,1) = R:Y(R) = 1: GOTO 660
  70. 650  VTAB 23: PRINT "<CTRL-G>INVALID TEAM # - TRY AGAIN!!": FOR DD = 1 TO 500: NEXT : GOTO 620
  71. 660  VTAB 22: HTAB 3: CALL  -958: PRINT N$(MA(Z,1));" AT ";N$(MA(Z,0))
  72. 670  VTAB 23: HTAB 10: PRINT "CORRECT (Y/N) ";: INPUT "";R$:R$ =  LEFT$(R$,1)
  73. 680  IF R$ = "N"  THEN Y(MA(Z,0)) = 0:Y(MA(Z,1)) = 0: GOTO 580
  74. 690 VT = MA(Z,0) -14 *(MA(Z,0) >14) +4:HT = 5 +20 *(MA(Z,0) >14)
  75. 700  VTAB VT: HTAB HT: PRINT "               "
  76. 710 VT = MA(Z,1) -14 *(MA(Z,1) >14) +4:HT = 5 +20 *(MA(Z,1) >14)
  77. 720  VTAB VT: HTAB HT: PRINT "               ": NEXT : FOR R = 1 TO 14:MA(R,2) = 0: NEXT R: GOTO 250
  78. 745  REM <CTRL-J><CTRL-J>*                   *       *** RANK DISPLAY  ***       *                   *<CTRL-J><CTRL-J>
  79. 750  TEXT : HOME : HTAB 12: PRINT "DISPLAY RANKINGS"
  80. 760 LL = 40:PR = 0: VTAB 10: PRINT "DO YOU WANT A PRINTOUT? ";: INPUT "";R$:R$ =  LEFT$(R$,1): IF R$ = "Y"  OR R$ = "Y"  THEN PR = 1: GOSUB 450
  81. 770  IF   NOT KEY  THEN 940
  82. 780 T1$ = " OFFENSIVE ": IF KEY >1  THEN T1$ = " DEFENSIVE ": IF KEY >2  THEN T1$ = " TOTAL "
  83. 785 T$ = "NFL" +T1$ +"RANKING LIST"
  84. 790  IF   NOT PR  THEN  HOME 
  85. 795  POKE 36,(LL - LEN(T$))/2: PRINT T$: IF PR  THEN  PRINT : IF  LEN(DT$) < >0  THEN  POKE 36,(LL - LEN(DT$))/2: PRINT DT$: PRINT 
  86. 800  POKE 36,1 +22 *PR: PRINT "RANK";: POKE 36,6 +22 *PR: PRINT "TOTAL";: POKE 36,12 +22 *PR: PRINT "TEAM NAME";: POKE 36,28 +22 *PR: PRINT "(OFF-DEF)": PRINT 
  87. 810  IF   NOT PR  THEN  POKE 34,3
  88. 820  FOR I = 1 TO 28: FOR H = 1 TO 28
  89. 830 L = R(H,KEY): IF R(H,0) = 999  THEN 850
  90. 840  IF L > = L1  THEN J = H:L1 = L
  91. 850  NEXT H
  92. 860 R(J,0) = 999
  93. 870  POKE 36,1 +22 *PR: PRINT  RIGHT$(" " + STR$(I),2);: POKE 36,7 +22 *PR: PRINT  RIGHT$(" " + STR$(R(J,3)),3);: POKE 36,12 +22 *PR: PRINT N$(J);: POKE 36,28 +22 *PR: PRINT "(";R(J,1);" - ";R(J,2);")"
  94. 880  IF   NOT PR  AND I = 18  THEN  PRINT : INPUT "PRESS <RETURN> TO SEE REST OF TEAMS.";R$: HOME 
  95. 890 L1 = 0: NEXT I
  96. 900  IF PR  THEN  PRINT  CHR$(12): PRINT D$;"PR#0"
  97. 910  PRINT : INPUT "PRESS <RETURN> TO SEE MENU ";R$
  98. 920  FOR I = 1 TO 28:R(I,0) = I: NEXT I
  99. 930  GOTO 250
  100. 940  IF   NOT PR  THEN  HOME 
  101. 950 T$ = "NFL ALPHABETIC RANKING LIST"
  102. 955  POKE 36,(LL - LEN(T$))/2: PRINT T$: IF PR  THEN  PRINT : IF  LEN(DT$) < >0  THEN  POKE 36,(LL - LEN(DT$))/2: PRINT DT$: PRINT 
  103. 960  POKE 36,1 +22 *PR: PRINT "RANK";: POKE 36,6 +22 *PR: PRINT "TOTAL";: POKE 36,12 +22 *PR: PRINT "TEAM NAME";: POKE 36,28 +22 *PR: PRINT "(OFF-DEF)": PRINT 
  104. 965  IF   NOT PR  THEN  POKE 34,3
  105. 970  FOR I = 1 TO 28
  106. 980  POKE 36,1 +22 *PR: PRINT  RIGHT$(" " + STR$(I),2);: POKE 36,7 +22 *PR: PRINT  RIGHT$(" " + STR$(R(I,3)),3);: POKE 36,12 +22 *PR: PRINT N$(I);: POKE 36,28 +22 *PR: PRINT "(";R(I,1);" - ";R(I,2);")"
  107. 990  IF   NOT PR  AND I = 18  THEN  PRINT : INPUT "PRESS <RETURN> TO SEE REST OF TEAMS.";R$: HOME 
  108. 1000  NEXT I
  109. 1010  IF PR  THEN  PRINT  CHR$(12): PRINT D$;"PR#0"
  110. 1020  PRINT : INPUT "PRESS <RETURN> TO SEE MENU ";R$
  111. 1030  FOR I = 1 TO 28:R(I,0) = I: NEXT I
  112. 1040  GOTO 250
  113. 1045  REM <CTRL-J>*                  *        **** SAVE FILES ****        *                  *<CTRL-J><CTRL-J>
  114. 1050  TEXT : HOME : HTAB 12: PRINT "SAVE FILES MENU"
  115. 1060  VTAB 10: PRINT " 1 - MATCHUPS FILE.": VTAB 15: PRINT " 2 - RANKINGS FILE."
  116. 1070  VTAB 21: PRINT "WHICH OPTION (1-2,<RETURN>=NONE) : ";: INPUT "";R$: IF R$ = ""  THEN 250
  117. 1080 CH =  VAL(R$): IF CH <1  OR CH >2  THEN 1050
  118. 1090  ON CH GOTO 1100,1150
  119. 1100  REM  PRINT D$;"UNLOCK NFL.MATCHUPS": PRINT D$;"OPEN NFL.MATCHUPS": PRINT D$;"DELETE NFL.MATCHUPS"
  120. 1110  PRINT D$;"OPEN NFL.MATCHUPS": PRINT D$;"WRITE NFL.MATCHUPS"
  121. 1120  FOR I = 1 TO 14: PRINT MA(I,0): PRINT MA(I,1): NEXT I
  122. 1130  PRINT D$;"CLOSE NFL.MATCHUPS": PRINT D$;"LOCK NFL.MATCHUPS"
  123. 1140  GOTO 1050
  124. 1150  REM  PRINT D$;"UNLOCK NFL.DATA": PRINT D$;"OPEN NFL.DATA": PRINT D$;"DELETE NFL.DATA"
  125. 1160  PRINT D$;"OPEN NFL.DATA": PRINT D$;"WRITE NFL.DATA"
  126. 1170  FOR I = 1 TO 28: PRINT R(I,1): PRINT R(I,2): PRINT R(I,3): NEXT I
  127. 1180  PRINT D$;"CLOSE NFL.DATA": PRINT D$;"LOCK NFL.DATA"
  128. 1190 WRIT = 1: GOTO 1050
  129. 1195  REM <CTRL-J>*                  *        *** PREDICTIONS  ***        *                  *<CTRL-J><CTRL-J>
  130. 1200 SA = (R(A,1) -R(B,2))/2 +21
  131. 1210 SB = (R(B,1) -R(A,2))/2 +21
  132. 1220 DTA =  ABS(SA -SB)
  133. 1230  RETURN 
  134. 1250  TEXT : HOME : HTAB 10: PRINT "PREDICT ALL MATCHUPS"
  135. 1260  VTAB 12: PRINT "DO YOU WANT A PRINTOUT?";: INPUT "";R$:R$ =  LEFT$(R$,1): IF R$ = "Y"  OR R$ = "Y"  THEN 1350
  136. 1270  VTAB 3: CALL  -958: FOR G = 1 TO 14:A = MA(G,0):B = MA(G,1)
  137. 1280 NA$ = N$(A) +" (HOME)":NB$ = N$(B): GOSUB 1200
  138. 1290  IF SA >SB  THEN  PRINT NA$;" OVER ";NB$: HTAB 25: PRINT "BY ";DTA;" POINTS."
  139. 1300  IF (SB >SA)  THEN  PRINT NB$;" OVER ";NA$: HTAB 25: PRINT "BY ";DTA;" POINTS."
  140. 1310  IF SA = SB  THEN  PRINT NA$;" AND ";NB$: HTAB 25: PRINT "WILL BE TIED."
  141. 1320  PRINT : IF G = 5  OR G = 10  THEN  PRINT : PRINT "PRESS <RETURN> TO CONTINUE";: INPUT "";R$: VTAB 3: CALL  -958
  142. 1330  NEXT G: PRINT "PRESS <RETURN> TO CONTINUE";: INPUT "";R$: GOTO 250
  143. 1350  GOSUB 450
  144. 1360 T$ = "NFL GAME PREDICTIONS": IF DT$ < >""  THEN T$ = T$ +" - " +DT$
  145. 1370  POKE 36,(LL - LEN(T$))/2: PRINT T$: PRINT 
  146. 1380  FOR G = 1 TO 14:A = MA(G,0):B = MA(G,1)
  147. 1390 NA$ = N$(A) +" (HOME)":NB$ = N$(B): GOSUB 1200
  148. 1400  IF SA >SB  THEN  PRINT NA$;" OVER ";NB$;" BY ";DTA;" POINTS."
  149. 1410  IF (SB >SA)  THEN  PRINT NB$;" OVER ";NA$;" BY ";DTA;" POINTS."
  150. 1420  IF SA = SB  THEN  PRINT NA$;" AND ";NB$;" WILL BE TIED."
  151. 1430  PRINT : NEXT G: PRINT D$;"PR#0": PRINT : PRINT "PRESS <RETURN> TO CONTINUE";: INPUT "";R$: GOTO 250
  152. 1440  TEXT : HOME : HTAB 8: PRINT "PREDICT INDIVIDUAL TEAMS"
  153. 1450  VTAB 8: CALL  -958: PRINT "GIVE ME THE FIRST TEAM'S NAME";: INPUT T$:T =  LEN(T$): FOR I = 1 TO 28: IF T$ =  LEFT$(N$(I),T)  THEN 1470
  154. 1460  NEXT I: PRINT : PRINT "I COULDN'T FIND A MATCH,TRY AGAIN...": FOR DD = 1 TO 1600: NEXT DD: GOTO 1450
  155. 1470 A = I: PRINT "IS THIS THE TEAM - ";N$(A);" ?";: INPUT "";R$: IF  LEFT$(R$,1) = "N"  THEN 1450
  156. 1480  VTAB 8: CALL  -958: PRINT "GIVE ME THE SECOND TEAM'S NAME";: INPUT T$:T =  LEN(T$): FOR I = 1 TO 28: IF T$ =  LEFT$(N$(I),T)  THEN 1500
  157. 1490  NEXT I: PRINT : PRINT "I COULDN'T FIND A MATCH,TRY AGAIN...": FOR DD = 1 TO 1600: NEXT DD: GOTO 1480
  158. 1500 B = I: PRINT "IS THIS THE TEAM - ";N$(B);" ?";: INPUT "";R$: IF  LEFT$(R$,1) = "N"  THEN 1480
  159. 1510 NA$ = N$(A):NB$ = N$(B): GOSUB 1200: PRINT : PRINT 
  160. 1520  IF SA >SB  THEN  PRINT NA$;" OVER ";NB$: HTAB 25: PRINT "BY ";DTA;" POINTS."
  161. 1530  IF (SB >SA)  THEN  PRINT NB$;" OVER ";NA$: HTAB 25: PRINT "BY ";DTA;" POINTS."
  162. 1540  IF SA = SB  THEN  PRINT NA$;" AND ";NB$: HTAB 25: PRINT "WILL BE TIED."
  163. 1550  PRINT : PRINT : PRINT "PRESS <RETURN> TO CONTINUE";: INPUT "";R$: GOTO 250
  164. 1600  GOSUB 1200
  165. 1610  VTAB 8: CALL  -958: PRINT "PLEASE ENTER ";N$(A);"'S": INPUT " SCORE : ";SI$:S1 =  VAL(SI$)
  166. 1615  VTAB 8: CALL  -958: PRINT N$(A);"'S SCORE IS ";S1;" CORRECT? ";: INPUT "";R$: IF  LEFT$(R$,1) = "N"  THEN 1610
  167. 1620  VTAB 12: CALL  -958: PRINT "PLEASE ENTER ";N$(B);"'S": INPUT " SCORE : ";SI$:S2 =  VAL(SI$)
  168. 1625  VTAB 12: CALL  -958: PRINT N$(B);"'S SCORE IS ";S2;" CORRECT? ";: INPUT "";R$: IF  LEFT$(R$,1) = "N"  THEN 1610
  169. 1630 R(A,1) =  FN I(R(A,1) +((S1 -SA)/4)):R(B,2) =  FN I(R(B,2) -((S1 -SA)/4))
  170. 1640 R(B,1) =  FN I(R(B,1) +((S2 -SB)/4)):R(A,2) =  FN I(R(A,2) -((S2 -SB)/4))
  171. 1645 R(A,3) = R(A,1) +R(A,2):R(B,3) = R(B,1) +R(B,2): RETURN 
  172. 1650  TEXT : HOME : HTAB 14: PRINT "UPDATE RATINGS"
  173. 1660  FOR G = 1 TO 14:A = MA(G,0):B = MA(G,1)
  174. 1670  VTAB 5: HTAB 15: CALL  -958: PRINT "GAME # ";G: GOSUB 1600
  175. 1680  NEXT G
  176. 1690 UPD = 1: GOTO 250
  177. 1700  TEXT : HOME : HTAB 4: PRINT "UPDATE INDIVIDUAL TEAM'S RATINGS"
  178. 1710  VTAB 8: CALL  -958: PRINT "GIVE ME THE FIRST TEAM'S NAME";: INPUT T$:T =  LEN(T$): FOR I = 1 TO 28: IF T$ =  LEFT$(N$(I),T)  THEN 1730
  179. 1720  NEXT I: PRINT : PRINT "I COULDN'T FIND A MATCH,TRY AGAIN...": FOR DD = 1 TO 1600: NEXT DD: GOTO 1710
  180. 1730 A = I: PRINT "IS THIS THE TEAM - ";N$(A);" ?";: INPUT "";R$: IF  LEFT$(R$,1) = "N"  THEN 1710
  181. 1740  VTAB 8: CALL  -958: PRINT "GIVE ME THE SECOND TEAM'S NAME";: INPUT T$:T =  LEN(T$): FOR I = 1 TO 28: IF T$ =  LEFT$(N$(I),T)  THEN 1760
  182. 1750  NEXT I: PRINT : PRINT "I COULDN'T FIND A MATCH,TRY AGAIN...": FOR DD = 1 TO 1600: NEXT DD: GOTO 1740
  183. 1760 B = I: PRINT "IS THIS THE TEAM - ";N$(B);" ?";: INPUT "";R$: IF  LEFT$(R$,1) = "N"  THEN 1740
  184. 1770  GOSUB 1600
  185. 1780 UPD = 1: GOTO 250
  186. 65535  REM ==================       ! NFL RANKER PROGRAM !      !         BY         !      !   DALE E. SALYER   !
  187. 65535  REM                   !      !  RANKER ALGORITHM  !      !         BY         !      !  JOSEPH M. FEEHAN  !      !                    !       ====================
  188. 65535  REM <*><*><*><*><*><*>       < THIS PROGRAM WAS   >      < ORIGINALLY PRINTED >      < IN "NIBBLE" VOL2#7 >      < BUT DID NOT HAVE   >      < ANY CAPABILITY TO  >
  189. 65535  REM ENTER OR SAVE THE >      < WEEKS MATCHUPS OF  >      < GAMES. THIS AND AN >      < EXTENDED MENU OF   >      < FEATURES HAVE BEEN >      < INCORPORATED INTO  >      < THE PROGRAM.       >      <*><*><*><*><*><*><*>